Prev: 89D3 Up: Map Next: 8C03
8A28: Start an attacker at a screen near the view
Used by the routine at spawn_cloud.
Fallen into from start_attacker, and jumped to by spawn_cloud for a cloud. Chooses one of the four screens the view overlaps, then a spawn point in it, fills the record, and gives up on a screen where it would be seen: see start_attacker.
start_at_edge 8A28 LD C,$00 Moving fast across: the screen ahead in X
8A2A LD A,(ship_across_speed)
8A2D AND A
8A2E JR Z,start_at_edge_1
8A30 INC A
8A31 JR Z,start_at_edge_1
8A33 LD A,(scroll_across)
8A36 BIT 7,A
8A38 JR NZ,start_at_edge_0
8A3A LD A,B
8A3B AND $01
8A3D LD B,A
8A3E JR start_at_edge_1
start_at_edge_0 8A40 LD C,$02
start_at_edge_1 8A42 LD A,(ship_down_speed) Moving fast up or down: the screen ahead in Y
8A45 AND A
8A46 JR Z,start_at_edge_2
8A48 INC A
8A49 JR Z,start_at_edge_2
8A4B INC C
8A4C LD A,(scroll_down)
8A4F BIT 7,A
8A51 JR NZ,start_at_edge_2
8A53 DEC C
8A54 LD A,B
8A55 AND $02
8A57 LD B,A
start_at_edge_2 8A58 LD A,$04 Four tries; the screen at random within B, forced by C
8A5A LD (speed_limit_down),A
8A5D LD A,(random_a)
8A60 AND B
8A61 OR C
start_in_screen 8A62 LD (scratch_count),A The screen's tile gives the allowed points (spawn_point_masks)
8A65 LD HL,map_window_tile_bytes
8A68 CALL add_a_to_hl
8A6B LD E,(HL)
8A6C LD HL,spawn_point_masks
8A6F ADD HL,DE
8A70 LD A,(HL)
8A71 LD (ground_cell),A
8A74 LD A,R A random point to start from; the rewritten BIT below tests it
8A76 AND $07
8A78 LD (row_count),A
8A7B ADD A,A
8A7C ADD A,A
8A7D ADD A,A
8A7E ADD A,$47
8A80 LD ($8A8B),A
8A83 XOR A
8A84 LD (row_count_spare),A
start_at_edge_3 8A87 LD A,(ground_cell) Round the eight points to an allowed one; none: next screen
8A8A RLC B
8A8C JR NZ,start_at_edge_4
8A8E LD A,(ground_cell)
8A91 RRCA
8A92 LD (ground_cell),A
8A95 LD A,(row_count_spare)
8A98 INC A
8A99 LD (row_count_spare),A
8A9C CP $08
8A9E JR NZ,start_at_edge_3
8AA0 JP start_at_edge_14
start_at_edge_4 8AA3 LD A,(row_count) The point's x and line (spawn_points)
8AA6 LD B,A
8AA7 LD A,(row_count_spare)
8AAA ADD A,B
8AAB AND $07
8AAD ADD A,A
8AAE LD HL,spawn_points
8AB1 CALL add_a_to_hl
8AB4 LD A,(HL)
8AB5 LD (IX+$02),A
8AB8 INC HL
8AB9 LD A,(HL)
8ABA LD (IX+$05),A
8ABD LD (IX+$0D),$FF Colour $FF, or $77 one time in four
8AC1 LD A,(random_b)
8AC4 AND $48
8AC6 JR NZ,start_at_edge_5
8AC8 LD (IX+$0D),$77
start_at_edge_5 8ACC LD A,(attacker_kind) Clear the record and fill it from the wave table (wave_table)
start_at_edge_6 8ACF ADD A,A
8AD0 ADD A,A
8AD1 LD HL,wave_table
8AD4 CALL add_a_to_hl
8AD7 CALL free_object
8ADA LD (IX+$15),$01
8ADE LD A,(HL)
8ADF LD (IX+$00),A
8AE2 INC HL
8AE3 LD A,(HL)
8AE4 LD (IX+$10),A
8AE7 INC HL
8AE8 LD A,(HL)
8AE9 LD (IX+$13),A
8AEC INC HL
8AED LD A,(HL)
8AEE LD (IX+$14),A
8AF1 LD A,(IX+$00)
8AF4 CP $1D
8AF6 JP Z,start_at_edge_19
8AF9 LD HL,(view_column) In the chosen screen's column and row
8AFC LD A,(scratch_count)
8AFF AND A
8B00 JR Z,start_at_edge_8
8B02 BIT 0,A
8B04 JR Z,start_at_edge_7
8B06 INC H
start_at_edge_7 8B07 BIT 1,A
8B09 JR Z,start_at_edge_8
8B0B LD A,(right_map_column)
8B0E LD L,A
start_at_edge_8 8B0F LD (IX+$01),L
8B12 LD (IX+$04),H
8B15 LD A,(IX+$00) A cloud: frame 0, or 1 now and then; screen rows 0-4 below
8B18 CP $13
8B1A JR NZ,start_at_edge_11
8B1C LD (IX+$13),$00
8B20 LD A,R
8B22 AND $1C
8B24 JR NZ,start_at_edge_9
8B26 INC (IX+$13)
start_at_edge_9 8B29 LD A,H
8B2A CP $05
8B2C JR NC,start_at_edge_13
8B2E LD (IX+$10),$23 Row 4, line $1F, level with the view
8B32 LD (IX+$04),$04
8B36 LD (IX+$05),$1F
8B3A LD (IX+$0D),$FF
8B3E LD A,(right_map_column)
8B41 CP L
8B42 JR Z,start_at_edge_10
8B44 LD A,(view_x)
8B47 SUB $30
8B49 JR C,start_at_edge_16
8B4B ADD A,$08
8B4D LD (IX+$02),A
8B50 RET
start_at_edge_10 8B51 LD A,(view_x)
8B54 LD (IX+$02),A
8B57 RET
start_at_edge_11 8B58 LD A,R Others: a colour from attacker_colours
8B5A AND $07
8B5C LD B,A
8B5D LD A,H
8B5E CP $0C
8B60 JR NC,start_at_edge_12
8B62 CP $04
8B64 JR C,start_at_edge_12
8B66 LD A,B
8B67 AND $03
8B69 LD B,A
start_at_edge_12 8B6A LD A,B
8B6B LD HL,attacker_colours
8B6E CALL add_a_to_hl
8B71 LD A,(HL)
8B72 LD (IX+$0D),A
start_at_edge_13 8B75 CALL place_on_screen In view: free it...
8B78 BIT 7,(IX+$10)
8B7C JR Z,start_at_edge_15
8B7E LD (IX+$00),$FF
start_at_edge_14 8B82 LD A,(speed_limit_down) ...and try the next screen
8B85 DEC A
8B86 LD (speed_limit_down),A
8B89 RET Z
8B8A LD A,(scratch_count)
8B8D INC A
8B8E AND $03
8B90 JP start_in_screen
start_at_edge_15 8B93 JP head_for_view Turn it towards the view
start_at_edge_16 8B96 LD (IX+$00),$FF Free it
8B9A RET
This entry point is used by the routine at start_attacker.
start_at_edge_17 8B9B LD IY,ship_record Meteor shower: at the ship, moved once by an X offset of -$30 to +$48 and a Y offset of $10 less the ship's +$1E (its line on the screen)
8B9F CALL copy_position
8BA2 LD A,(random_a)
8BA5 LD B,A
8BA6 AND $30
8BA8 ADD A,$18
8BAA BIT 7,B
8BAC JR Z,start_at_edge_18
8BAE SUB $18
8BB0 NEG
start_at_edge_18 8BB2 LD (IX+$07),A
8BB5 LD A,(IY+$1E)
8BB8 SUB $10
8BBA NEG
8BBC LD (IX+$09),A
8BBF CALL move_object
8BC2 LD A,(view_column) A comet (kind 9) in the view's own column, a rock (8) otherwise
8BC5 CP (IX+$01)
8BC8 LD A,$09
8BCA JP Z,start_at_edge_6
8BCD DEC A
8BCE JP start_at_edge_6
start_at_edge_19 8BD1 LD A,(random_a) Type $1D: 2 or 4 pixels a pass down, 2 or 4 right...
8BD4 AND $08
8BD6 SRL A
8BD8 SRL A
8BDA ADD A,$02
8BDC LD (IX+$09),A
8BDF LD A,(random_b)
8BE2 AND $08
8BE4 SRL A
8BE6 SRL A
8BE8 ADD A,$02
8BEA LD (IX+$07),A
8BED NEG ...or left, outside the view's own column
8BEF LD B,A
8BF0 LD A,(view_column)
8BF3 CP (IX+$01)
8BF6 LD (IX+$0D),$FE
8BFA RET Z
8BFB LD (IX+$07),B
8BFE LD (IX+$0D),$EE
8C02 RET
Prev: 89D3 Up: Map Next: 8C03